;;; Metacircular interpreter for optional lazy evaluation.
;;; This is a hacked version of the lazy evaluator in the book.
;;; The inherent wierdness is that it ISN'T lazy except where
;;; explicitly told to be by a keyword.
;;;
;;; The syntax of formal parameters to abstactions changes.
;;; The evaluator has to be able to ask if an argument is "lazy?"
;;;  in which case it is evaluated lazily, or "memo?" in which case
;;;  it is evaluated lazily with memoization.
;;; An example of the corresponding concrete syntax might be
;;; (define (foo x (y lazy) (z lazy-memo))  ... body...)
;;;   which will have the argument bound to x evaluated, 
;;;   the argument bound to y turned intl a thunk, 
;;;   and the argument to z turned into a "memoized thunk"

;;; Beware: the word "quit" has special meaning to the driver loop.
;;; If you use it in your program as a variable name, don't try
;;; to get its value from the driver loop.
;;;
;;; When quit is typed at the driver loop, the driver quits back to the 
;;; underlying Scheme implementation.  This is to prevent nuisances with
;;; Dr Scheme, where quitting by pressing the EOF button will cause further
;;; reads to get EOF until the definitions are re-executed (Dr Scheme v207).


;;; Some extensions in MIT Scheme that need to be defined for Dr. Scheme

(define true #t)
(define false #f)
(define nil '())

;;; Code that lz-eval normally imports from mz-eval.
(define (self-evaluating? exp)
  (cond ((number? exp) true)
        ((string? exp) true)
        (else false)))

(define (quoted? exp)
  (tagged-list? exp 'uml:quote))

(define (text-of-quotation exp) (cadr exp))

(define (tagged-list? exp tag)
  (if (pair? exp)
      (eq? (car exp) tag)
      false))

(define (variable? exp) (symbol? exp))

(define (assignment? exp)
  (tagged-list? exp 'uml:set!))

(define (assignment-variable exp) (cadr exp))

(define (assignment-value exp) (caddr exp))


(define (definition? exp)
  (tagged-list? exp 'uml:define))

(define (definition-variable exp)
  (if (symbol? (cadr exp))
      (cadr exp)
      (caadr exp)))

(define (definition-value exp)
  (if (symbol? (cadr exp))
      (caddr exp)
      (make-lambda (cdadr exp)
                   (cddr exp))))

(define (lambda? exp) (tagged-list? exp 'uml:lambda))

(define (lambda-parameters exp) (cadr exp))
(define (lambda-body exp) (cddr exp))

(define (make-lambda parameters body)
  (cons 'uml:lambda (cons parameters body)))


(define (if? exp) (tagged-list? exp 'uml:if))

(define (if-predicate exp) (cadr exp))

(define (if-consequent exp) (caddr exp))

(define (if-alternative exp)
  (if (not (null? (cdddr exp)))
      (cadddr exp)
      'false))

(define (make-if predicate consequent alternative)
  (list 'uml:if predicate consequent alternative))


(define (begin? exp) (tagged-list? exp 'uml:begin))

(define (begin-actions exp) (cdr exp))

(define (last-exp? seq) (null? (cdr seq)))
(define (first-exp seq) (car seq))
(define (rest-exps seq) (cdr seq))

(define (sequence->exp seq)
  (cond ((null? seq) seq)
        ((last-exp? seq) (first-exp seq))
        (else (make-begin seq))))

(define (make-begin seq) (cons 'uml:begin seq))


(define (application? exp) (pair? exp))
(define (operator exp) (car exp))
(define (operands exp) (cdr exp))

(define (no-operands? ops) (null? ops))
(define (first-operand ops) (car ops))
(define (rest-operands ops) (cdr ops))


(define (cond? exp) (tagged-list? exp 'uml:cond))

(define (cond-clauses exp) (cdr exp))

(define (cond-else-clause? clause)
  (eq? (cond-predicate clause) 'else))

(define (cond-predicate clause) (car clause))

(define (cond-actions clause) (cdr clause))

(define (cond->if exp)
  (expand-clauses (cond-clauses exp)))

(define (expand-clauses clauses)
  (if (null? clauses)
      'false                          ; no else clause
      (let ((first (car clauses))
            (rest (cdr clauses)))
        (if (cond-else-clause? first)
            (if (null? rest)
                (sequence->exp (cond-actions first))
                (error "ELSE clause isn't last -- COND->IF"
                       clauses))
            (make-if (cond-predicate first)
                     (sequence->exp (cond-actions first))
                     (expand-clauses rest))))))

;;;
;;; environment handling
;;;
(define (enclosing-environment env) (cdr env))

(define (first-frame env) (car env))

(define the-empty-environment '())

(define (make-frame variables values)
  (cons variables values))

(define (frame-variables frame) (car frame))
(define (frame-values frame) (cdr frame))

(define (add-binding-to-frame! var val frame)
  (set-car! frame (cons var (car frame)))
  (set-cdr! frame (cons val (cdr frame))))

(define (extend-environment vars vals base-env)
  (if (= (length vars) (length vals))
      (cons (make-frame vars vals) base-env)
      (if (< (length vars) (length vals))
          (error "Too many arguments supplied" vars vals)
          (error "Too few arguments supplied" vars vals))))

(define (lookup-variable-value var env)
  (define (env-loop env)
    (define (scan vars vals)
      (cond ((null? vars)
             (env-loop (enclosing-environment env)))
            ((eq? var (car vars))
             (car vals))
            (else (scan (cdr vars) (cdr vals)))))
    (if (eq? env the-empty-environment)
        (error "Unbound variable" var)
        (let ((frame (first-frame env)))
          (scan (frame-variables frame)
                (frame-values frame)))))
  (env-loop env))

(define (set-variable-value! var val env)
  (define (env-loop env)
    (define (scan vars vals)
      (cond ((null? vars)
             (env-loop (enclosing-environment env)))
            ((eq? var (car vars))
             (set-car! vals val))
            (else (scan (cdr vars) (cdr vals)))))
    (if (eq? env the-empty-environment)
        (error "Unbound variable -- SET!" var)
        (let ((frame (first-frame env)))
          (scan (frame-variables frame)
                (frame-values frame)))))
  (env-loop env))

(define (define-variable! var val env)
  (let ((frame (first-frame env)))
    (define (scan vars vals)
      (cond ((null? vars)
             (add-binding-to-frame! var val frame))
            ((eq? var (car vars))
             (set-car! vals val))
            (else (scan (cdr vars) (cdr vals)))))
    (scan (frame-variables frame)
          (frame-values frame))))

;;;
;;;SECTION 4.1.3
;;;
(define (true? x)
  (not (eq? x false)))

(define (false? x)
  (eq? x false))

 
(define (make-procedure parameters body env)
  (list 'procedure parameters body env))

(define (compound-procedure? p)
  (tagged-list? p 'procedure))


(define (procedure-parameters p) (cadr p))
(define (procedure-body p) (caddr p))
(define (procedure-environment p) (cadddr p))


;;;SECTION 4.1.4

(define (setup-environment)
  (let ((initial-env
         (extend-environment (primitive-procedure-names)
                             (primitive-procedure-objects)
                             the-empty-environment)))
    (define-variable! 'true true initial-env)
    (define-variable! 'false false initial-env)
    initial-env))

(define (primitive-procedure? proc)
  (tagged-list? proc 'primitive))

(define (primitive-implementation proc) (cadr proc))

(define primitive-procedures
  (list (list 'uml:car car)
        (list 'uml:cdr cdr)
        (list 'uml:cons cons)
        (list 'uml:null? null?)
	(list 'uml:+ +)
	(list 'uml:- -)
	(list 'uml:/ /)
	(list 'uml:* *)
	(list 'uml:= =)
	(list 'uml:equal? equal?)
	(list 'uml:eqv? eqv?)
	(list 'uml:eq? eq?)
	(list 'uml:member member)
	(list 'uml:memv memv)
	(list 'uml:memq memq)
	(list 'uml:> >)
	(list 'uml:expt expt)
	(list 'uml:rem remainder)
	(list 'uml:display display)
	(list 'uml:newline newline)
        ))

(define (primitive-procedure-names)
  (map car
       primitive-procedures))

(define (primitive-procedure-objects)
  (map (lambda (proc) (list 'primitive (cadr proc)))
       primitive-procedures))

(define (apply-primitive-procedure proc args)
  (apply (primitive-implementation proc) args))

;;; common parts of driver loop
(define (prompt-for-input string)
  (newline) (newline) (display string) (newline))

(define (announce-output string)
  (newline) (display string) (newline))

(define (user-print object)
  (if (compound-procedure? object)
      (display (list 'compound-procedure
                     (procedure-parameters object)
                     (procedure-body object)
                     '<procedure-env>))
      (display object)))

;;;
;;; Code from the lazy evaluator, hacked for optional laziness, 
;;; and new keywords.
;;;

(define (lz-eval exp env)
  (cond ((self-evaluating? exp) exp)
        ((variable? exp) (lookup-variable-value exp env))
        ((quoted? exp) (text-of-quotation exp))
        ((assignment? exp) (lz-eval-assignment exp env))
        ((definition? exp) (lz-eval-definition exp env))
        ((if? exp) (lz-eval-if exp env))
        ((lambda? exp)
         (make-procedure (lambda-parameters exp)
                         (lambda-body exp)
                         env))
        ((begin? exp) 
         (lz-eval-sequence (begin-actions exp) env))
        ((cond? exp) (lz-eval (cond->if exp) env))
        ((application? exp)		;**
         (lz-apply (actual-value (operator exp) env)
                (operands exp)
                env))
        (else
         (error "Unknown expression type -- LZ-EVAL" exp))))

(define (actual-value exp env)
  (force-it (lz-eval exp env)))

;; extended from lazy evaluator
(define (lz-apply procedure arguments env)
  (cond ((primitive-procedure? procedure)
         (apply-primitive-procedure 
	  procedure 
	  (list-of-arg-values arguments env))) ; args to primops always eval'd
        ((compound-procedure? procedure)
         (lz-eval-sequence
          (procedure-body procedure)
          (let ((params (procedure-parameters procedure))) ;more-changes
            (extend-environment 
             (map parameter-name params)
             (list-of-delayed-args params arguments env) ;more-changes
             (procedure-environment procedure)))))
        (else (error "Unknown procedure type -- LZ-APPLY" procedure))))

;; back to verbatim from lazy evaluator
(define (list-of-arg-values exps env)
  (if (no-operands? exps)
      '()
      (cons (actual-value (first-operand exps) env)
            (list-of-arg-values (rest-operands exps)
                                env))))

;; extended from lazy evaluator
(define (list-of-delayed-args var-decls exps env) ;more-changes
  (if (no-operands? exps)
      '()
      (cons (delay-it (first-variable var-decls) (first-operand exps) env)
            (list-of-delayed-args (rest-variables var-decls) 
				  (rest-operands exps) 
				  env))))

;; If, as in lazy evaluator.
(define (lz-eval-if exp env)
  (if (true? (actual-value (if-predicate exp) env))
      (lz-eval (if-consequent exp) env)
      (lz-eval (if-alternative exp) env)))

;;; The following are the same as mc-eval, 
;;;  except involves recursive evaluation and we have changed name of evaluator
;;;  so we move them out of the common code.

(define (lz-eval-sequence exps env)
  (cond ((last-exp? exps) (lz-eval (first-exp exps) env))
        (else (lz-eval (first-exp exps) env)
              (lz-eval-sequence (rest-exps exps) env))))

(define (lz-eval-assignment exp env)
  (set-variable-value! (assignment-variable exp)
                       (lz-eval (assignment-value exp) env)
                       env)
  'ok)

(define (lz-eval-definition exp env)
  (define-variable! (definition-variable exp)
                    (lz-eval (definition-value exp) env)
                    env)
  'ok)

(define input-prompt ";;; OPT-L-Eval input:")
(define output-prompt ";;; OPT-L-Eval value:")

(define (driver-loop)
  (prompt-for-input input-prompt)
  (let ((input (read)))
    (if (not (equal? input 'quit))
	(begin
	  (let ((output
		 (actual-value input the-global-environment)))
	    (announce-output output-prompt)
	    (user-print output))
	  (driver-loop))
	'exiting-driver-loop)))

;;; Thunk handling, changed a bit from lazy evaluator
(define (delay-it decl exp env) ;more-changes
  (cond ((not (declaration? decl))      (lz-eval exp env))
        ((lazy? decl)                   (list 'thunk exp env))
        ((memo? decl)                   (list 'thunk-memo exp env))
        (else (error "unknown variable declaration:" decl))))
         
(define (thunk? obj) (tagged-list? obj 'thunk))
(define (memoized-thunk? obj) (tagged-list? obj 'thunk-memo)) ;more-changes
(define (evaluated-thunk? obj) (tagged-list? obj 'evaluated-thunk))
(define (thunk-exp thunk) (cadr thunk))
(define (thunk-env thunk) (caddr thunk))
(define (thunk-value evaluated-thunk) (cadr evaluated-thunk))

;; memoizing version of force-it
(define (force-it obj) ;more-changes
  (cond ((thunk? obj) (actual-value (thunk-exp obj) (thunk-env obj)))
        ((memoized-thunk? obj)
         (let ((result (actual-value (thunk-exp obj) (thunk-env obj))))
           (set-car! obj 'evaluated-thunk)
           (set-car! (cdr obj) result)  ; replace exp with its value
           (set-cdr! (cdr obj) '())     ; forget unneeded env
           result))
        ((evaluated-thunk? obj) (thunk-value obj))
        (else obj)))

;; Changes to concrete syntax for lazy and lazy-memo keywords


(define (first-variable var-decls) (car var-decls))
(define (rest-variables var-decls) (cdr var-decls))
(define declaration? pair?)
(define (parameter-name var-decl) (if (pair? var-decl)  
				      (car var-decl)  
				      var-decl))
(define (lazy? var-decl) (and (pair? var-decl) 
			      (eq? 'lazy (cadr var-decl))))
(define (memo? var-decl) (and (pair? var-decl) 
			      (eq? 'lazy-memo (cadr var-decl))))


(define the-global-environment 'uninitialized)

(define (olz-eval-loop)
  (set! the-global-environment (setup-environment))
  (driver-loop))
  
#|  Scheme multiline, nestable comment as per SRFI 30 

;; Code for chatty-gcd: this prints "rem " whenever it is about to perform
;; a remainder operation.

(uml:define (gcd a b)
  (uml:if (uml:= b 0)
      a
      (gcd b 
	   (uml:begin
	     (uml:display "rem ")
	     (uml:rem a b))))) 

(gcd 206 40)


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; Versions of cons: select one at a time for experimenting

;; stream
(uml:define (cons car-part (cdr-part lazy)) 
  (uml:lambda (m) (m car-part cdr-part)))

;; memo stream
(uml:define (cons car-part (cdr-part lazy-memo)) 
  (uml:lambda (m) (m car-part cdr-part)))

;; fully lazy
(uml:define (cons (car-part lazy) (cdr-part lazy)) 
  (uml:lambda (m) (m car-part cdr-part)))

;; memo lazy
(uml:define (cons (car-part lazy-memo) (cdr-part lazy-memo)) 
  (uml:lambda (m) (m car-part cdr-part)))

;; eager 
(uml:define (cons car-part (cdr-part lazy)) 
  (uml:lambda (m) (m car-part cdr-part)))

;;; End of multiple versions of cons
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

(uml:define (car z) 
  (z (uml:lambda (car-part cdr-part) car-part)))
(uml:define (cdr z) 
  (z (uml:lambda (car-part cdr-part) cdr-part)))


(uml:define (list-ref items n)
  (uml:if (uml:= n 0)
      (car items)
      (list-ref (cdr items) (uml:- n 1))))

;; Unused in problem set
;;(uml:define (map proc items)
;;  (uml:if (uml:null? items)
;;      '()
;;      (cons (proc (car items))
;;            (map proc (cdr items)))))

;; Unused in problem set
;;(uml:define (scale-list items factor)
;;  (map (uml:lambda (x) (uml:* x factor))
;;       items))

(uml:define (add-lists list1 list2)
  (uml:cond ((uml:null? list1) list2)
            ((uml:null? list2) list1)
            (else (cons (uml:+ (car list1) (car list2))
                        (add-lists (cdr list1) (cdr list2))))))

(uml:define ones (cons 1 ones))

;; example to explore for streams, memoization.
(uml:define chatty-integers
  (cons 0
    (uml:begin (uml:display "recurr ")
      (add-lists ones chatty-integers))))

;;(list-ref chatty-integers 4)

;; It is important that if you are using memoization, that you re-define 
;; "chatty-integers" when you want to start a new experiment, otherwise
;; any memoization done previously will still be there.

|#