;;;METACIRCULAR EVALUATOR FROM CHAPTER 4 (SECTIONS 4.1.1-4.1.4) of
;;; STRUCTURE AND INTERPRETATION OF COMPUTER PROGRAMS


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;Variant of code in ch4.scm:
;;; eval renamed mc-eval    or lz-eval
;;; apply renamed mc-apply  or lz-apply
;;; to distinguish from eval and apply in underlying scheme inplementation.
;;; Keywords for the language being evaluated are the Scheme keywords prefixed
;;; with "uml:"
;;;
;;; Changes: 
;;; o  'quit at evaluator command prompt causes the evaluator to exit
;;; o Restructured code to get two versions of applicative order evaluators
;;;     and two versions of normal order evaluators into same file.
;;; o Added some test code at end.
;;;
;;; (mc-eval #f)  Runs book's Scheme evaluator from 4.1.1-4.1.4
;;; (mc-eval #t)  Runs variant language with dynamic binding (dynamic scope)
;;; (lz-eval #f)  Runs book's normal-order evaluator from 4.2
;;; (lz-eval #t)  Runs book's normal-order evaluator with memoization 4.2
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

(load "sicp.ss")
(require (lib "trace.ss"))


;;; common code for mc-eval, lz-eval

;;;SECTION 4.1.2

(define (self-evaluating? exp)
  (cond ((number? exp) true)
        ((string? exp) true)
        (else false)))

(define (quoted? exp)
  (tagged-list? exp 'uml:quote))

(define (text-of-quotation exp) (cadr exp))

(define (tagged-list? exp tag)
  (if (pair? exp)
      (eq? (car exp) tag)
      false))

(define (variable? exp) (symbol? exp))

(define (assignment? exp)
  (tagged-list? exp 'uml:set!))

(define (assignment-variable exp) (cadr exp))

(define (assignment-value exp) (caddr exp))


(define (definition? exp)
  (tagged-list? exp 'uml:define))

(define (definition-variable exp)
  (if (symbol? (cadr exp))
      (cadr exp)
      (caadr exp)))

(define (definition-value exp)
  (if (symbol? (cadr exp))
      (caddr exp)
      (make-lambda (cdadr exp)
                   (cddr exp))))

(define (lambda? exp) (tagged-list? exp 'uml:lambda))

(define (lambda-parameters exp) (cadr exp))
(define (lambda-body exp) (cddr exp))

(define (make-lambda parameters body)
  (cons 'uml:lambda (cons parameters body)))

(define (let? exp) (tagged-list? exp 'uml:let))
(define (let-bindings exp) (cadr exp))
(define (let-body exp) (cddr exp))

(define (let-var binding) (car binding))
(define (let-val binding) (cadr binding))

(define (if? exp) (tagged-list? exp 'uml:if))

(define (if-predicate exp) (cadr exp))

(define (if-consequent exp) (caddr exp))

(define (if-alternative exp)
  (if (not (null? (cdddr exp)))
      (cadddr exp)
      'false))

(define (make-if predicate consequent alternative)
  (list 'uml:if predicate consequent alternative))


(define (begin? exp) (tagged-list? exp 'uml:begin))

(define (begin-actions exp) (cdr exp))

(define (last-exp? seq) (null? (cdr seq)))
(define (first-exp seq) (car seq))
(define (rest-exps seq) (cdr seq))

(define (sequence->exp seq)
  (cond ((null? seq) seq)
        ((last-exp? seq) (first-exp seq))
        (else (make-begin seq))))

(define (make-begin seq) (cons 'uml:begin seq))


(define (application? exp) (pair? exp))
(define (operator exp) (car exp))
(define (operands exp) (cdr exp))

(define (no-operands? ops) (null? ops))
(define (first-operand ops) (car ops))
(define (rest-operands ops) (cdr ops))


(define (cond? exp) (tagged-list? exp 'uml:cond))

(define (cond-clauses exp) (cdr exp))

(define (cond-else-clause? clause)
  (eq? (cond-predicate clause) 'else))

(define (cond-predicate clause) (car clause))

(define (cond-actions clause) (cdr clause))

(define (cond->if exp)
  (expand-clauses (cond-clauses exp)))

(define (expand-clauses clauses)
  (if (null? clauses)
      'false                          ; no else clause
      (let ((first (car clauses))
            (rest (cdr clauses)))
        (if (cond-else-clause? first)
            (if (null? rest)
                (sequence->exp (cond-actions first))
                (error "ELSE clause isn't last -- COND->IF"
                       clauses))
            (make-if (cond-predicate first)
                     (sequence->exp (cond-actions first))
                     (expand-clauses rest))))))


;;; environment handling
(define (enclosing-environment env) (cdr env))

(define (first-frame env) (car env))

(define the-empty-environment '())

(define (make-frame variables values)
  (cons variables values))

(define (frame-variables frame) (car frame))
(define (frame-values frame) (cdr frame))

(define (add-binding-to-frame! var val frame)
  (set-car! frame (cons var (car frame)))
  (set-cdr! frame (cons val (cdr frame))))

(define (extend-environment vars vals base-env)
  (if (= (length vars) (length vals))
      (cons (make-frame vars vals) base-env)
      (if (< (length vars) (length vals))
          (error "Too many arguments supplied" vars vals)
          (error "Too few arguments supplied" vars vals))))

(define (lookup-variable-value var env)
  (define (env-loop env)
    (define (scan vars vals)
      (cond ((null? vars)
             (env-loop (enclosing-environment env)))
            ((eq? var (car vars))
             (car vals))
            (else (scan (cdr vars) (cdr vals)))))
    (if (eq? env the-empty-environment)
        (error "Unbound variable" var)
        (let ((frame (first-frame env)))
          (scan (frame-variables frame)
                (frame-values frame)))))
  (env-loop env))

(define (set-variable-value! var val env)
  (define (env-loop env)
    (define (scan vars vals)
      (cond ((null? vars)
             (env-loop (enclosing-environment env)))
            ((eq? var (car vars))
             (set-car! vals val))
            (else (scan (cdr vars) (cdr vals)))))
    (if (eq? env the-empty-environment)
        (error "Unbound variable -- SET!" var)
        (let ((frame (first-frame env)))
          (scan (frame-variables frame)
                (frame-values frame)))))
  (env-loop env))

(define (define-variable! var val env)
  (let ((frame (first-frame env)))
    (define (scan vars vals)
      (cond ((null? vars)
             (add-binding-to-frame! var val frame))
            ((eq? var (car vars))
             (set-car! vals val))
            (else (scan (cdr vars) (cdr vals)))))
    (scan (frame-variables frame)
          (frame-values frame))))

;;;SECTION 4.1.3
(define (true? x)
  (not (eq? x false)))

(define (false? x)
  (eq? x false))

 
(define (make-procedure parameters body env)
  (list 'procedure parameters body env))

(define (compound-procedure? p)
  (tagged-list? p 'procedure))


(define (procedure-parameters p) (cadr p))
(define (procedure-body p) (caddr p))
(define (procedure-environment p) (cadddr p))


;;;SECTION 4.1.4

(define (setup-environment)
  (let ((initial-env
         (extend-environment (primitive-procedure-names)
                             (primitive-procedure-objects)
                             the-empty-environment)))
    (define-variable! 'true true initial-env)
    (define-variable! 'false false initial-env)
    initial-env))

(define (primitive-procedure? proc)
  (tagged-list? proc 'primitive))

(define (primitive-implementation proc) (cadr proc))

(define primitive-procedures
  (list (list 'uml:car car)
        (list 'uml:cdr cdr)
        (list 'uml:cons cons)
        (list 'uml:null? null?)
	(list 'uml:+ +)
	(list 'uml:- -)
	(list 'uml:/ /)
	(list 'uml:* *)
	(list 'uml:= =)
	(list 'uml:equal? equal?)
	(list 'uml:eqv? eqv?)
	(list 'uml:eq? eq?)
	(list 'uml:> >)
	(list 'uml:expt expt)
	(list 'uml:rem remainder)
	(list 'uml:display display)
        ))

(define (primitive-procedure-names)
  (map car
       primitive-procedures))

(define (primitive-procedure-objects)
  (map (lambda (proc) (list 'primitive (cadr proc)))
       primitive-procedures))

(define (apply-primitive-procedure proc args)
  (apply (primitive-implementation proc) args))

;;; common parts of driver loop
(define (prompt-for-input string)
  (newline) (newline) (display string) (newline))

(define (announce-output string)
  (newline) (display string) (newline))

(define (user-print object)
  (if (compound-procedure? object)
      (display (list 'compound-procedure
                     (procedure-parameters object)
                     (procedure-body object)
                     '<procedure-env>))
      (display object)))

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


;;;SECTION 4.1.1
(define (run-mc-eval dynamic?)

(define (mc-eval exp env)
  (cond ((self-evaluating? exp) exp)
        ((variable? exp) (lookup-variable-value exp env))
        ((quoted? exp) (text-of-quotation exp))
        ((assignment? exp) (eval-assignment exp env))
        ((definition? exp) (eval-definition exp env))
        ((if? exp) (eval-if exp env))

        ((lambda? exp)
	 (if dynamic?
	     ;; dynamic scope: no need to store environment
	     (make-procedure (lambda-parameters exp)
			     (lambda-body exp)
			     '*no-environment*)
	     ;; lexical (static) scope: Scheme
	     (make-procedure (lambda-parameters exp)
			     (lambda-body exp)
			     env)))
        ((begin? exp) 
         (eval-sequence (begin-actions exp) env))
        ((cond? exp) (mc-eval (cond->if exp) env))

	((let? exp)
	 (eval-sequence
	  (let-body exp)
	  (extend-environment (map let-var (let-bindings exp))
			      (map let-val (let-bindings exp))
			      env)))
	   
        ((application? exp)
	 (if dynamic?
	     ;; dynamic scope: apply takes current environment
	     (dyn-apply (mc-eval (operator exp) env)
			(list-of-values (operands exp) env)
			env)
	     ;; lexical (static) scope, Scheme: get env from procedure
	     (mc-apply (mc-eval (operator exp) env)
		       (list-of-values (operands exp) env))))
        (else
         (error "Unknown expression type -- EVAL" exp))))

(define (mc-apply procedure arguments)
  (cond ((primitive-procedure? procedure)
         (apply-primitive-procedure procedure arguments))
        ((compound-procedure? procedure)
         (eval-sequence
           (procedure-body procedure)
           (extend-environment
             (procedure-parameters procedure)
             arguments
             (procedure-environment procedure))))
        (else
         (error
          "Unknown procedure type -- APPLY" procedure))))

(define (dyn-apply procedure arguments calling-env) ;extra parameter
  (cond ((primitive-procedure? procedure)
         (apply-primitive-procedure procedure arguments))
        ((compound-procedure? procedure)
         (eval-sequence
           (procedure-body procedure)
           (extend-environment
             (procedure-parameters procedure)
             arguments
             calling-env)))		; changed here
        (else
         (error
          "Unknown procedure type -- APPLY" procedure))))


(define (list-of-values exps env)
  (if (no-operands? exps)
      '()
      (cons (mc-eval (first-operand exps) env)
            (list-of-values (rest-operands exps) env))))

(define (eval-if exp env)
  (if (true? (mc-eval (if-predicate exp) env))
      (mc-eval (if-consequent exp) env)
      (mc-eval (if-alternative exp) env)))

(define (eval-sequence exps env)
  (cond ((last-exp? exps) (mc-eval (first-exp exps) env))
        (else (mc-eval (first-exp exps) env)
              (eval-sequence (rest-exps exps) env))))

(define (eval-assignment exp env)
  (set-variable-value! (assignment-variable exp)
                       (mc-eval (assignment-value exp) env)
                       env)
  'ok)

(define (eval-definition exp env)
  (define-variable! (definition-variable exp)
                    (mc-eval (definition-value exp) env)
                    env)
  'ok)

;;;SECTION 4.1.3

(define input-prompt ";;; MC-Eval input:")
(define output-prompt ";;; MC-Eval value:")

(define (driver-loop)
  (prompt-for-input input-prompt)
  (let ((input (read)))
    (if (not (equal? input '(quote quit)))
	(begin
	  (let ((output (mc-eval input the-global-environment)))
	    (announce-output output-prompt)
	    (user-print output))
	  (driver-loop))
	'exiting-driver-loop)))


(define the-global-environment (setup-environment))
(driver-loop)

)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(define (run-lz-eval memoize?)

(define (lz-eval exp env)
  (cond ((self-evaluating? exp) exp)
        ((variable? exp) (lookup-variable-value exp env))
        ((quoted? exp) (text-of-quotation exp))
        ((assignment? exp) (eval-assignment exp env))
        ((definition? exp) (eval-definition exp env))
        ((if? exp) (lz-eval-if exp env))
        ((lambda? exp)
         (make-procedure (lambda-parameters exp)
                         (lambda-body exp)
                         env))
        ((begin? exp) 
         (eval-sequence (begin-actions exp) env))
        ((cond? exp) (lz-eval (cond->if exp) env))
        ((application? exp)		;**
         (lz-apply (actual-value (operator exp) env)
                (operands exp)
                env))
        (else
         (error "Unknown expression type -- LZ-EVAL" exp))))

(define (actual-value exp env)
  (force-it (lz-eval exp env)))

(define (lz-apply procedure arguments env)
  (cond ((primitive-procedure? procedure)
         (apply-primitive-procedure
          procedure
          (list-of-arg-values arguments env))) ; changed
        ((compound-procedure? procedure)
         (eval-sequence
          (procedure-body procedure)
          (extend-environment
           (procedure-parameters procedure)
           (list-of-delayed-args arguments env) ; changed
           (procedure-environment procedure))))
        (else
         (error
          "Unknown procedure type -- APPLY" procedure))))

(define (list-of-arg-values exps env)
  (if (no-operands? exps)
      '()
      (cons (actual-value (first-operand exps) env)
            (list-of-arg-values (rest-operands exps)
                                env))))

(define (list-of-delayed-args exps env)
  (if (no-operands? exps)
      '()
      (cons (delay-it (first-operand exps) env)
            (list-of-delayed-args (rest-operands exps)
                                  env))))

(define (lz-eval-if exp env)
  (if (true? (actual-value (if-predicate exp) env))
      (lz-eval (if-consequent exp) env)
      (lz-eval (if-alternative exp) env)))

(define input-prompt ";;; L-Eval input:")
(define output-prompt ";;; L-Eval value:")

(define (driver-loop)
  (prompt-for-input input-prompt)
  (let ((input (read)))
    (if (not (equal? input '(quote quit)))
	(begin
	  (let ((output
		 (actual-value input the-global-environment)))
	    (announce-output output-prompt)
	    (user-print output))
	  (driver-loop))
	'exiting-driver-loop)))

(define (force-it obj)
  (if (thunk? obj)
      (actual-value (thunk-exp obj) (thunk-env obj))
      obj))

(define (delay-it exp env)
  (list 'thunk exp env))

(define (thunk? obj)
  (tagged-list? obj 'thunk))

(define (thunk-exp thunk) (cadr thunk))
(define (thunk-env thunk) (caddr thunk))

(define (evaluated-thunk? obj)
  (tagged-list? obj 'evaluated-thunk))

(define (thunk-value evaluated-thunk) (cadr evaluated-thunk))

(define (memoizing-force-it obj)
  (cond ((thunk? obj)
         (let ((result (actual-value
                        (thunk-exp obj)
                        (thunk-env obj))))
           (set-car! obj 'evaluated-thunk)
           (set-car! (cdr obj) result)  ; replace exp with its value
           (set-cdr! (cdr obj) '())     ; forget unneeded env
           result))
        ((evaluated-thunk? obj)
         (thunk-value obj))
        (else obj)))


;;; Same as mc-eval, except involves recursive evaluation and we have
;;; changed name of evaluator

(define (eval-sequence exps env)
  (cond ((last-exp? exps) (lz-eval (first-exp exps) env))
        (else (lz-eval (first-exp exps) env)
              (eval-sequence (rest-exps exps) env))))

(define (eval-assignment exp env)
  (set-variable-value! (assignment-variable exp)
                       (lz-eval (assignment-value exp) env)
                       env)
  'ok)

(define (eval-definition exp env)
  (define-variable! (definition-variable exp)
                    (lz-eval (definition-value exp) env)
                    env)
  'ok)

;;; 
;;; start lazy evaluator
;;;

(define the-global-environment (setup-environment))

(if memoize?
    (set! force-it memoizing-force-it))


(driver-loop)

)

;;; some code for mc-eval demo
#|
(run-mc-eval #f)

(uml:define (uml:square x) (uml:* x x))
(uml:define (uml:compose f g) (uml:lambda (x) (f (g x))))
(uml:define (uml:inc x) (uml:+ x 1))
((uml:compose uml:square uml:inc) 5)
|#


;;; lexical versus dynamic scope examples
#|

;; (run-mc-eval #f)
;; versus
;; (run-mc-eval #t)

(uml:define (foo x) (bar 20))
(uml:define (bar y) (uml:+ x y))
(foo 22)
'quit

(uml:define (inc z) (uml:+ z 1))
(uml:define (sum term a next b)
  (uml:if (uml:> a b)
          0
          (uml:+ (term a)
                 (sum term (next a) next b))))

(uml:define (sum-powers a b n)
  (uml:define (nth-power x)
     (uml:expt x n))
  (sum nth-power a inc b))

(sum-powers 2 3 2)

;; change "next" to "n" in sum
(uml:define (sum term a n b)
  (uml:if (uml:> a b)
          0
          (uml:+ (term a)
                 (sum term (n a) next b))))

(sum-powers 2 3 2)
;; should give error: n dynamically bound to procedure inc.
'quit
|#

;;; normal vs applicative order examples
#|

;; (run-mc-eval #f)
;; versus
;; (run-lz-eval #f)


(uml:define (foo x)
   (uml:display "evaluating foo, ")
   (uml:+ x x))

(foo (uml:begin (uml:display "eval arg, ") 2))

'quit

;;

(uml:define (try a b)   (uml:if (uml:= a 0) 1 b))

(try 0 (uml:/ 1 0))

;; also versus
;; (run-lz-eval #t)

(uml:define (gcd a b)
  (uml:if (uml:= b 0)
      a
      (gcd b 
	   (uml:begin
	     (uml:display "rem ")
	     (uml:rem a b))))) 

(gcd 206 40)

;; (run-lz-eval #t)
;; lazy lists: replace Scheme cons, car, cdr
;; with "Church pairs" 
(uml:define (cons car-part cdr-part) 
  (uml:lambda (m) (m car-part cdr-part)))
(uml:define (car z) 
  (z (uml:lambda (car-part cdr-part) car-part)))
(uml:define (cdr z) 
  (z (uml:lambda (car-part cdr-part) cdr-part)))

;; More stream stuff for example...
(uml:define (list-ref items n)
  (uml:if (uml:= n 0)
      (car items)
      (list-ref (cdr items) (uml:- n 1))))

(uml:define (map proc items)
  (uml:if (uml:null? items)
      '()
      (cons (proc (car items))
            (map proc (cdr items)))))

(uml:define (scale-list items factor)
  (map (uml:lambda (x) (uml:* x factor))
       items))

(uml:define (add-lists list1 list2)
  (uml:cond ((uml:null? list1) list2)
            ((uml:null? list2) list1)
            (else (cons (uml:+ (car list1) (car list2))
                        (add-lists (cdr list1) (cdr list2))))))

(uml:define ones (cons 1 ones))

(uml:define integers (cons 1 (add-lists ones integers)))

;; only run following line with memoizing #t
; (list-ref integers 17)

;; example of need for memoization: simple recurrence
(uml:define (chatty-integers n)
  (cons n
    (uml:begin (uml:display "recurr on ") 
      (uml:display n) (uml:display "\n")
      (chatty-integers (uml:+ n 1)))))

(list-ref (chatty-integers 1) 5)

;; example of need for memoization: quadratic
(uml:define chatty-integers2
  (cons 0
    (uml:begin (uml:display "recurr ")
      (add-lists ones chatty-integers2))))

(list-ref chatty-integers2 5)

|#